Vla-displayのソースを表示

{{AutoLISP}}
; 構文
: (vla-display ''vla-object'' ''status'')


; 機能
: ペーパー空間ビューポートの表示コントロールをオン・オフの切り替え。



; 引数
:* vla-object … VLAオブジェクト (PViewport)
:* status… ブール値（:vlax-true = ビューポート表示オン or :vlax-flase =  = ビューポート表示オフ）



; 戻り値
: nil



* memo :
** ペーパー空間ビューポートの表示コントロールをオンにしてから、MSpace プロパティを使用してモデル空間の編集機能をアクティブにする。 
** ViewportOn プロパティを使って、ペーパー空間のビューポート表示が既にこのメソッドでオンになっているかどうかを確認する。 



; サンプル
<pre class="brush:autolisp;">
((vl-load-com)
(defun c:Exp_ViewportOn()
    ;; 2個のペーパー空間ビューポートを作成してから、
    ;; ビューポートのステータスをチェックする。
    (setq *actdoc* (vla-get-ActiveDocument (vlax-get-acad-object)))
    
    ;; ペーパー空間ビューポートを定義
    (setq center (vlax-3d-point 3 3 0)
          width  10
          height 10)
    
    ;; モデル空間からペーパー空間に変更
    (vla-put-ActiveSpace *actdoc* acPaperSpace)
    
    ;; ペーパー空間ビューポートを作成
    (setq paperSpace (vla-get-PaperSpace *actdoc*))
    (setq pviewportObj1 (vla-AddPViewport paperSpace center width height))
  
    ;; 2個めのペーパー空間ビューポートを定義
    (setq center (vlax-3d-point 8 8 0)
          width  10
          height 10)

    (setq pviewportObj2 (vla-AddPViewport paperSpace center width height))
    
    ;; ペーパー空間ビューポートをアクティブにする前に、
    ;; MSPACE プロパティを True にしておく
    (vla-Display pviewportObj1 :vlax-true)

    (vla-put-MSpace *actdoc* :vlax-true)
    (vla-put-ActivePViewport *actdoc* pviewportObj1)
    (vla-Regen *actdoc* acAllViewports)                   ; 全再作図

    (alert (strcat "pviewportObj1 は " (if (= (vla-get-ViewportOn pviewportObj1) :vlax-true) "on." "not on.")
                   "\npviewportObj2 は " (if (= (vla-get-ViewportOn pviewportObj2) :vlax-true) "on." "not on.")))

    ;; pviewportObj2 をオンにする
    (vla-Display pviewportObj2 :vlax-true)

    (alert (strcat "pviewportObj1 は " (if (= (vla-get-ViewportOn pviewportObj1) :vlax-true) "on." "not on.")
                   "\npviewportObj2 は " (if (= (vla-get-ViewportOn pviewportObj2) :vlax-true) "on." "not on.")))
)

</pre>

-----
関連事項
* [[vlax-get-acad-object]]
* [[vla-get-activedocument]]
* [[vla-get-paperspace]]
* [[vla-addpviewport]]
* [[vla-put-mspace]]
* [[vla-put-activepviewport]]
* [[vla-regen]]
* [[vlax-3d-point]]


[[Category:AutoLISP]]