Vla-put-urlのソースを表示

{{AutoLISP}}
; 構文
: (vla-put-url ''vla-object'' ''url'')


; 機能
: Hyperlink オブジェクトの URL を指定する。  


; 引数
:* vla-object …  Hyperlink の VLAオブジェクト
:* url … Hyperlink オブジェクトの URL を表す文字列。 

; 戻り値
: nil


* 注意 ： ファイルは、ローカル ドライブ、ネットワーク ドライブ、インターネットの場所、イントラネットの場所のどこに保存されていてもかまわない。


; サンプル
<pre class="brush:autolisp;">
(vl-load-com)
(defun c:Example_URL()
    ;; 円を作成して、ハイパーリンクを追加するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;; 円の定義
    (setq centerPoint (vlax-3d-point 0 0 0)  
          radius 5)
    
    ;; 円を生成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq circleObj (vla-AddCircle modelSpace centerPoint radius))

    (vla-ZoomAll acadObj)

    ;; 円のハイパーリンクコレクションを取得
    (setq Hyperlinks (vla-get-Hyperlinks circleObj))

    ;; ハイパーリンクコレクションを追加
    (setq Hyperlink (vla-Add Hyperlinks "GizmoLabs"))
    (vla-put-URL Hyperlink "wiki.gz-labs.net")
    (vla-put-URLDescription Hyperlink "GizmoLabs Wiki")
    (vla-put-URLNamedLocation Hyperlink "MY_LOCATION")

    ;; ハイパーリンクの内容を読み取って表示
    (setq HLList "")
    (vlax-for Hyperlink Hyperlinks
        (setq HLList (strcat HLList "____________________________________"   ;; セパレータ
                             "\nURL: " (vla-get-URL Hyperlink)
                             "\nURL の概要 : " (vla-get-URLDescription Hyperlink)
                             "\nURL ロケーション名: " (vla-get-URLNamedLocation Hyperlink)))
    )
    
    (alert (strcat "円が持っている " (itoa (vla-get-Count Hyperlinks)) " ハイパーリンク: \n"  HLList))
)
</pre>

-----
関連事項
* [[vlax-get-acad-object]]
* [[vla-get-activedocument]]
* [[vla-put-url]]
* [[vla-get-url]]
* [[vla-put-urldescription]]
* [[vla-get-urldescription]]
* [[vla-get-urlnamedlocation]]
* [[vla-put-urlnamedlocation]]
* [[vla-get-hyperlinks]]


[[Category:AutoLISP]]